blognote-info.com

Les fichiers ini sont des fichiers contenant des données de façon organiséesen subdivision qui elle même contiennet des rubrique auxquelles on peut associer des valeurs...

Il est possible de tout programmer, mais les dll font des choses magnifiques :

 Declare Function GetPrivateProfileString Lib "kernel32" _
   Alias "GetPrivateProfileStringA" ( _
       ByVal lpApplicationName As String, _
       ByVal lpKeyName As Any, _
       ByVal lpDefault As String, _
       ByVal lpReturned As String, _
       ByVal nSize As Long, _
       ByVal lpFileName As String) As Long
 
 Declare Function WritePrivateProfileString Lib "kernel32" _
   Alias "WritePrivateProfileStringA" ( _
       ByVal lpApplicationName As String, _
       ByVal lpKeyName As Any, _
       ByVal lpString As Any, _
       ByVal lpFileName As String) As Long
 
 Declare Function WritePrivateProfileSection Lib "kernel32" _
   Alias "WritePrivateProfileSectionA" ( _
       ByVal lpApplicationName As String, _
       ByVal lpString As Any, _
       ByVal lpFileName As String) As Long

Voici pour la partie des importations de dll ...

Il faut maintenant redéfinir les fonctions permettant d'utiliser ces déclarations :

 Function GetIni(Section As String, Rubrique As String) As String
   Dim FicIni$, Buffer As String
   Dim lgBuf%, lgRep%
   FicIni = Application.ThisWorkbook.Path & "\param.ini"
   Buffer = Space$(255)
   lgBuf = 255    
   lgRep = GetPrivateProfileString(Section, Rubrique, "", Buffer, lgBuf, FicIni)  
   GetIni = Left$(Buffer, lgRep)
 End Function
 
 Sub PutIni(Section As String, Rubrique As String, Valeur As String)
   Dim FicIni$
   FicIni = Application.ThisWorkbook.Path & "\param.ini"
   WritePrivateProfileString Section, Rubrique, Valeur, FicIni
 End Sub
 
 Sub DelIni(Section As String, Rubrique As String)
   Dim FicIni$
   FicIni = Application.ThisWorkbook.Path & "\param.ini"
   WritePrivateProfileString Section, Rubrique, 0&, FicIni
 End Sub

Donc ici nous avons défini un fichier ini par défaut mais il est possible de le passer en paramètre ...
Il y a donc trois fonctions permettant respectivement d'ajouter, de prendre et de retirer des informations dans un fichier ini...

J'espère que ça aidera quelqu'un !!